TerraformでAWSリソース1種類を複数個作成する

-
ここんとこTerraformづくしです。前回はAPIGatewayとLambdaとSNSとS3を一気にまとめて作成するものを作ったわけですが、諸般の事情から複数のDynamoDBと複数のLambdaそして複数のAPIGateway、、はてはS3まで準備しないといけなくなったので、いろいろと試行錯誤しながら準備しました。

1つのリソースを複数個用意するとかいうサンプルがなかなかなかったので
役に立つかなと思って備忘録として残しておきます。
＊なんかもっと効率いい方法あれば教えてほしい。

そしてTerraformはプログラムではないのでforとかifの使い方に癖があるし
結構な制約事項となります。けれども、1個覚えればどこのクラウドだろうが
オンプレだろうが1つの記述法で行けるというのは非常に魅力的なんですよねぇ。


◆設定

1.terraformファイル群

 (1)ルートに置くもの

# main.tf
-----------------
resource "aws_sns_topic" "this_sns_topic" {
  name = var.sns_topic_name
}

module "lambda" {
  source = "./lambda"
}

module "apigateway" {
  source        = "./apigateway"
  region        = var.region
  account_id    = var.account_id
}

module "dymano" {
  source = "./dynamodb"
}

module "s3" {
  source = "./s3"
}
-----------------
# variables.tf
-----------------
variable "access_key" {
  description = "AWS Access Key"
}
variable "secret_key" {
  description = "AWS Secret Key"
}
variable "role_arn" {
  description = "AWS Role ARN for Assume Role"
}
variable "region" {
  description = "AWS Region"
  default     = "ap-northeast-1"
}

variable "sns_topic_name" {
  default = "sns_dev_topic"
}

variable "account_id" {
  default = "XXXXXXX"
}
-----------------
# provider.tf
-----------------
provider "aws" {
  access_key = var.access_key
  secret_key = var.secret_key
  region     = var.region
}
-----------------

(2)Lambdaディレクトリ配下 


# main.tf
-----------------
data "archive_file" "arc_dev_function" {
  for_each    = var.import_lambda_dirs
  type        = "zip"
  source_dir  = "${path.module}/src/${lookup(each.value, "filename")}"
  output_path = "${path.module}/upload/${lookup(each.value, "filename")}.zip"
}

resource "aws_lambda_function" "lambda_functions" {
  for_each         = var.import_lambda_dirs
  filename         = "${path.module}/upload/${lookup(each.value, "filename")}.zip"
  function_name    = lookup(each.value, "filename")
  role             = var.lambda_function_arn
  handler          = "lambda_function.lambda_handler"
  source_code_hash = base64sha256("${path.module}/upload/${lookup(each.value, "filename")}.zip")
  runtime          = var.lambda_runtime
  memory_size      = var.lambda_memory
  timeout          = var.lambda_timeout

  environment {
    variables = lookup(each.value, "environment_setting")
  }
  tags = lookup(each.value, "tag_setting")
}
-----------------
# variables.tf
-----------------
variable "import_lambda_dirs" {
  default = {
    dir1 = {
      filename = "01_sample"
      environment_setting = {
        ENV_SAMPLE = "sample1"
      }
      tag_setting = {
        "tag" = "sample1"
      }
    }
    dir2 = {
      filename = "02_sample"
      environment_setting = {
        ENV_SAMPLE = "sample2"
      }
      tag_setting = {
        "tag" = "sample2"
      }
    }
    dir3 = {
      filename = "03_sample"
      environment_setting = {
        ENV_SAMPLE = "sample3"
      }
      tag_setting = {
        "tag" = "sampl3"
      }
    }
  }
}

variable "lambda_role_arn" {
  default = "AWS Role ARN for Assume Role"
}
variable "lambda_runtime" {
  default = "python3.8"
}

variable "lambda_memory" {
  default = 128
}
variable "lambda_timeout" {
  default = 30
}

variable "lambda_function_arn" {
  default = "arn:aws:iam::XXXXX:role/LambdaRole"
}
-----------------

(3)APIGatewayディレクトリ配下 


# main.tf
-----------------
data "template_file" "apigateway_template" {
  for_each = var.apigateway_param
  template = file("${path.module}/swagger_definition/${lookup(each.value, "filename")}.yml")
  vars = {
    region        = var.region
    account_id    = var.account_id
    function_name = lookup(each.value, "functionname")
    base_path     = lookup(each.value, "basepath")
  }
}

resource "aws_api_gateway_rest_api" "my_api_gateway" {
  for_each    = var.apigateway_param
  name        = lookup(each.value, "filename")
  description = "This is my API for demonstration purposes"
  body        = data.template_file.apigateway_template[each.key].rendered
}

resource "aws_api_gateway_deployment" "apiDeployment" {
  for_each    = var.apigateway_param
  rest_api_id = aws_api_gateway_rest_api.my_api_gateway[each.key].id
  stage_name  = lookup(each.value, "basepath")
}

resource "aws_lambda_permission" "lambda_permission" {
  for_each      = var.apigateway_param
  statement_id  = "AllowMyDemoAPIInvoke"
  action        = "lambda:InvokeFunction"
  function_name = lookup(each.value, "functionname")
  principal     = "apigateway.amazonaws.com"
  source_arn    = "${aws_api_gateway_rest_api.my_api_gateway[each.key].execution_arn}/*/*/*"
}
-----------------
# variables.tf
-----------------
variable "region" {}
variable "account_id" {}

variable "apigateway_param" {
  default = {
    param1 = {
      index        = 0
      filename     = "sample1"
      functionname = "01_sample"
      basepath     = "test"
    }
    param2 = {
      index        = 1
      filename     = "sample2"
      functionname = "02_sample"
      basepath     = "test"
    }
    param3 = {
      index        = 2
      filename     = "sample3"
      functionname = "03_sample"
      basepath     = "test"
    }
  }
}
-----------------

(4)DynamoDBディレクトリ配下 


# main.tf
-----------------
resource "aws_dynamodb_table" "basic-dynamodb-table1" {
  for_each     = var.hash_range_param
  name         = lookup(each.value, "table_name")
  billing_mode = "PAY_PER_REQUEST"
  hash_key     = lookup(each.value, "table_hashkey")
  range_key    = lookup(each.value, "table_rangekey")

  attribute {
    name = lookup(each.value, "table_hashkey")
    type = lookup(each.value, "hash_type")
  }

  attribute {
    name = lookup(each.value, "table_rangekey")
    type = lookup(each.value, "hash_type")
  }

  tags = lookup(each.value, "tags")
}

resource "aws_dynamodb_table" "basic-dynamodb-table2" {
  for_each     = var.hash_only_param
  name         = lookup(each.value, "table_name")
  billing_mode = "PAY_PER_REQUEST"
  hash_key     = lookup(each.value, "table_hashkey")

  attribute {
    name = lookup(each.value, "table_hashkey")
    type = lookup(each.value, "type")
  }

  tags = lookup(each.value, "tags")
}
-----------------
# variables.tf
-----------------
variable "hash_range_param" {
  default = {
    param1 = {
      index          = 0
      table_name     = "hash_range_sample1"
      table_hashkey  = "hash_key"
      table_rangekey = "range_key"
      hash_type      = "S"
      range_type     = "S"
      tags = {
        tag = "sample1"
      }
    }
    param2 = {
      index          = 1
      table_name     = "hash_range_sample2"
      table_hashkey  = "hash_key"
      table_rangekey = "range_key"
      hash_type      = "S"
      range_type     = "S"
      tags = {
        tag = "sample2"
      }
    }
  }
}

variable "hash_only_param" {
  default = {
    param1 = {
      index         = 0
      table_name    = "hash_only_sample1"
      table_hashkey = "key_id"
      type          = "S"
      tags = {
        tag = "sample1"
      }
    }
    param2 = {
      index         = 1
      table_name    = "hash_only_sample2"
      table_hashkey = "key_id"
      type          = "S"
      tags = {
        tag = "sample2"
      }
    }
  }
}
-----------------

(5)S3ディレクトリ配下 


# main.tf
-----------------
resource "aws_s3_bucket" "bucket" {
  for_each = var.buckets
  bucket   = lookup(each.value, "bucket_name")
  acl      = lookup(each.value, "acl")
  tags     = lookup(each.value, "tags")
}
-----------------
# variables.tf
-----------------
variable "buckets" {
  default = {
    param1 = {
      index       = 0
      bucket_name = "sample-bucket-20200517-1"
      acl         = "private"
      tags = {
        tag = "sample1"
      }
    }
    param2 = {
      index       = 1
      bucket_name = "sample-bucket-20200517-2"
      acl         = "private"
      tags = {
        tag = "sample2"
      }
    }
  }
}
-----------------

2.ディレクトリ構造 


|-- apigateway
|   |-- main.tf
|   |-- swagger_definition
|   |   |-- sample1.yml
|   |   |-- sample2.yml
|   |   `-- sample3.yml
|   `-- variables.tf
|-- dynamodb
|   |-- main.tf
|   `-- variables.tf
|-- lambda
|   |-- main.tf
|   |-- src
|   |   |-- 01_sample
|   |   |   `-- lambda_function.py
|   |   |-- 02_sample
|   |   |   `-- lambda_function.py
|   |   `-- 03_sample
|   |       `-- lambda_function.py
|   |-- upload
|   `-- variables.tf
|-- main.tf
|-- provider.tf
|-- s3
|   |-- main.tf
|   `-- variables.tf
|-- terraform.tfstate
|-- terraform.tfstate.backup
`-- variables.tf

3.実行コマンド

$ terraform init
$ terraform plan
$ terraform apply
$ terraform destroy


◆参考

・複数リソース作り方

https://qiita.com/ringo/items/875f08ec550f0826f0dc
https://dev.classmethod.jp/articles/terraform-network-variable/
https://cloudfish.hatenablog.com/entry/2020/02/19/183548
https://dev.classmethod.jp/articles/terraform_count_delete/
https://qiita.com/keiichi-hikita/items/9fd20e8ad6afe4e5ef72
https://febc-yamamoto.hatenablog.jp/entry/2018/02/02/120207

・環境変数関連

https://qiita.com/tksugimoto/items/c1dd29a587e5689a1f6a

・APIGateway

https://medium.com/@jmarhee/using-for-each-in-terraform-in-modules-7fb5a240a0d9

・DynamoDB

https://www.terraform.io/docs/providers/aws/r/dynamodb_table.html
https://github.com/terraform-providers/terraform-provider-aws/issues/3176

コメント

コメントを投稿

このブログの人気の投稿

GASでGoogleDriveのサブフォルダとファイル一覧を出力する

-
 タイトルのまんまです。 以前、EXCELで似たようなこと をしていたのでGASではどうするのかなぁと思ってやってみました。まぁほとんど丸パクリです。とりあえず、また使うかもしれないので自分用にメモです。しかしGASでGoogleDriveのファイル一覧嘗め回そうとすると3分かかってしまう。数が多いと6分制限に引っかかるのでこれでは使えない。せいぜい100ファイルとか数が少ないところで使う分にはいいけどダイナミックな場合は何回かに分割してやらないと少し厳しいかもしれない。 ◆GAS //設定値取得 const SHEET_URL = SpreadsheetApp.getActiveSpreadsheet().getUrl(); const ss = SpreadsheetApp.openByUrl(SHEET_URL); const SETTING_SHEET = ss.getSheetByName('設定') const TARGET_FOLDER_ID = SETTING_SHEET.getRange('B2').getValue(); const SAVE_FOLDER_ID = SETTING_SHEET.getRange('B3').getValue(); const SAVE_FILE_NAME = SETTING_SHEET.getRange('B4').getValue(); const SAVE_SHEET_NAME = SETTING_SHEET.getRange('B5').getValue(); function writeSheet(values, labels, sheetUrl, sheetname, width) { /* スプレッドシートに書き出し */ try { if (values.length > 0) { // シートを追加する let spreadSheet = SpreadsheetApp.openByUrl(sheetUrl); let sheet = set_sheet(sheetUrl,sheetname); // 1行目だけヘッダ追加 let he...
続きを読む

証券外務員1種勉強(計算式暗記用メモ)

-
何を血迷ったのか 証券外務員 1種を受けてみようかと 思って 問題集 を回していたけれども、いまいち数式部分に 弱いところがあるので暗記してやろうと 重要そうな数式を集めてみました。まぁ正確性は低いかもしんないけど ひとまずは個人用でメモしています。 1.株式業務 (1) 権利落ち相場 　　権利落ち相場= 権利付相場 ÷ 分割比率 　(2)採算株価 　　採算株価=希望利回り÷1株当たり配当年額 　(3)1株当たりキャッシュフロー(PCFR) 　　 PCFR = 発行済株式総数 ÷( 税引後純利益 + 減価償却費 ) 　(4) イールドスプレッド 　　イールドスプレッド=長期債利回りー 株式益回り 　(5) EVITDA (金利・税金・償却前利益) 　　EVITDA=税引前利益+支払利息+減価償却費 　(6) EV (企業価値) 　　EV= 時価総額 + 有利子負債 ー 現金預金 ー 短期有価証券 　(7) EV/EVITDA倍率 (倍) 　　EV/EVITDA倍率=EV÷EVITDA 　◆株価成立参照 　　 https://www.rakuten-sec.co.jp/web/domestic/stock/rule/agreed.html 　　 http://money-magazine.org/%E6%A0%AA%E4%BE%A1%E3%81%AE%E6%B1%BA%E3%81%BE%E3%82%8A%E6%96%B9%E3%81%AE%E5%9F%BA%E7%A4%8E%E7%9F%A5%E8%AD%98/ 　　 https://kabusyo.com/keiken/q_baibai.html 　　 https://ja.wikipedia.org/wiki/%E6%A0%AA%E4%BE%A1 　　 http://kabukiso.com/basics/buy/ita.html 2.債券業務 (1) パリティ価格 (転換社債株式価値) 　　パリティ価格=(株価÷ 転換価格 )×100 　(2) 乖離率 (%) 　　乖離率={(転換社債の時価ーパリティ価格)÷パリティ価格}×100 　(3) 最終利回り (%) 　　最終利回り={利率+(償還価格ー購入価格)÷ 残存期間 ＜年＞)}÷購入価格×...
続きを読む

マクロ経済学(IS-LM分析)

-
イメージ
危うく3日坊主になりそうでした。とりあえず今日は 「IS-LM分析」 です。 テキストでは 簡便4象限法 とかいうのの説明が多いです。なのでさっぱり わけわからん状態ですが、それなりに頑張ってみます。 1: IS曲線 の導出 財市場の均衡を表す。Iは投資を表し、Sは貯蓄を表す。 ・IS曲線導出の材料 I→利子率の関数、S→所得の関数で「I=S」で財市場を表す。 ・ 投資関数 利子率の減少関数、I (投資関数)=I(r)　※rは利子率 ・政府活動の導入 裁量的な拡張的な財政政策はIS曲線をシフトさせる。 IS曲線の右シフト=政府支出の増大や減税等の有効需要を増加させる要因による 2: LM曲線 の導出 利子率の低下が国民所得の増大につながる因果関係を明らかにする目的 ・LM曲線導出の材料 貨幣需要(MD)=L、L=取引的動機+予備的動機(L1)+投機的動機(L2) MD=L1+L2 貨幣供給(Ms)=名目貨幣供給/物価(P) ・LM曲線のシフト 金融緩和策・物価下落：実質貨幣供給(MS)が増大→右(下)へシフト 金融引締策・物価上昇：実質貨幣供給(MS)が減少→左(上)へシフト 独立投資拡大→IS曲線が右にシフト 利子率がr1→r2に下落する。 IS曲線、LM曲線の均衡点がE→Fに移動する。 国民所得がY1→Yfとなって増大する。 3:特殊なLM曲線 ・ 流動性の罠 のLM曲線 金融政策は無効→LM曲線をシフトさせても均衡点Eは変わらない IS曲線を右にシフトさせる拡張的な財政政策を実施すると均衡点が E→E´となり国民所得がY1→Y2に増加するので財政政策は有効となる。　　　 ・ 投資の利子率に対する弾力性ゼロ 金融政策は無効→LM曲線を右にシフトさせても国民所得が増えない。 流動性の罠と同じくIS曲線を右にシフトさせる拡張的な財政政策を実施すると 均衡点がE→E´となり国民所得がY1→Y2に増加するので財政政策は有効となる。　　　　　　 4: クラウディング・アウト 政府が市場に介入して公共投資を行うと民間の投資が締出しを受ける ・古典派による財政政策の無効論 政府支出を拡大すると利子率が上昇してしまい。投資が減少する。 政府の支出がクラウディングアウトを引き起こして支...
続きを読む